// Circle Crawlers
// joel gillman   January, 2008
// Minneapolis, Minnesota
// lab.joelgillman.com

// Processing 0135

int numCrawlers = 2000;
int numAnomalys = 200;
Crawler[] bugs;
Anomaly[] flys;
boolean drawLines = true;
int mode = 1;

float friction = 0.9;

void setup() {  
  size(470,470);

  background(0);
  frameRate(30);
  smooth();
  noStroke();

  bugs = new Crawler[numCrawlers];
  flys = new Anomaly[numAnomalys];

  for (int i=0; i<numCrawlers; i++) {
    int index = i;
    bugs[index] = new Crawler(width/2,height/2);
  }

  for (int i=0; i<numAnomalys; i++) {
    int index = i;
    flys[index] = new Anomaly(width/2,height/2,random(5,20));
  }
}

void draw()
{
  //fade lines
  if (drawLines) {
    noStroke();
    fill(0, 10);
    rect(0,0,width,height);
  } 
  else {
    background(0);
  }
  
  for(int i=0; i<numAnomalys; i++) {
    flys[i].move();
    flys[i].display();
  }
  for(int i=0; i<numCrawlers; i++) {
    bugs[i].move();
    bugs[i].display();
  }
}

void keyReleased () {
  if (key == ' ') {
    if (drawLines) {
      drawLines = false;
    } 
    else if (!drawLines) {
      drawLines = true; 
    }
  }
  if (key == 'r') {
    background(0);
    for(int i=0; i<numCrawlers; i++) {
      bugs[i].ax = bugs[i].ay = bugs[i].vx = bugs[i].vy = 0;
      bugs[i].xpos = width/2;
      bugs[i].ypos = height/2;
    }
    for(int i=0; i<numAnomalys; i++) {
      flys[i].ax = flys[i].ay = flys[i].vx = flys[i].vy = 0;
      flys[i].xpos = width/2;
      flys[i].ypos = height/2;
    }
  }
}

//Class definitions-------------------===============
class Bug
{
  float vx;
  float vy;
  float ax;
  float ay;
  float xpos;
  float ypos;
  float maxDist;

  Bug() {
    maxDist = random(height/4,height/2);
  }

  void move () {
    vx += random(-1,1);
    vy += random(-1,1);

    vx *= friction;
    vy *= friction;

    xpos += vx;
    ypos += vy;

    switch (mode) {
    case 1:
      if (dist(xpos,ypos,width/2,height/2) > maxDist) {
        vx = vy = ax = ay = 0;
        xpos = width/2;
        ypos = height/2;
      }
      break;
    }
  }
}

class Anomaly extends Bug
{
  float sizer;
  Anomaly (float ixp, float iyp, float isize) {
    xpos = ixp;
    ypos = iyp;
    sizer = isize;
    maxDist = map(sizer,5,20,150,50);
    noStroke();
    fill(255,map(sizer,5,20,100,50));
    //fill(180);
    ellipse(xpos,ypos,sizer,sizer); 
  }

  void display() {
    noStroke();
    fill(255,map(sizer,5,20,100,20));
    //fill(180);
    ellipse(xpos,ypos,sizer,sizer);
  }
}

class Crawler extends Bug
{
  Crawler (float ixp, float iyp) {
    xpos = ixp;
    ypos = iyp;
    stroke(255);
    point(xpos,ypos);
  }

  void display() {
    stroke(255);
    point(xpos,ypos);
  }

}